version 9
capture log close
set more off
log using ehd4.log, replace

use rrdat1, clear

gen     des = 2                          /*lateral moves*/
replace des = 1 if (presn/pres -1)>0.2   /*upward moves*/
replace des = 3 if (presn/pres -1)<0.0   /*downward moves*/
replace des = 0 if presn==-1

gen tf    = tfin - tstart + 1      /*ending time*/

gen coho2 = tb >= 468 & tb <= 504  /*cohort 2*/
gen coho3 = tb >= 588 & tb <= 624  /*cohort 3*/
gen lfx   = tstart - te            /*labor force experience*/
gen pnoj  = noj - 1                /*previous number of jobs*/

set seed 339487731   /*specify the initial value of the random-number seed*/ 

gen r = uniform()    /*uniformly distributed pseudorandom numbers*/
                     /*on the interval [0,1)*/

stset tf, fail(des==2)   /*define single episode data*/ 

streg edu coho2 coho3 lfx pnoj pres if r <=84/219, ///
dist(e) nohr            /*fit parametric survival model: lateral*/

stset tf, fail(des==3)  /*define single episode data*/ 

streg edu coho2 coho3 lfx pnoj pres if r <=84/96, ///
dist(e) nohr            /*fit parametric survival model: downward*/

log close