version 9
capture log close
set more off
log using ehf1.log, replace

use rrdat1, clear

gen des = tfin ~= ti                /*destination state*/
gen ts  = 0                         /*starting time*/
gen tf  = tfin - tstart + 1         /*ending time*/

gen coho2 = tb >= 468 & tb <= 504   /*cohort 2*/
gen coho3 = tb >= 588 & tb <= 624   /*cohort 3*/
gen lfx   = tstart - te             /*labor force experience*/
gen pnoj  = noj - 1                 /*previous number of jobs*/

gen marrdate  = tmar - tstart   /*variables for episode splitting*/
gen entrymarr = marrdate>0 & marrdate<tf

gen newid = _n
expand 2 if entrymarr           /*episode splitting*/

by newid, sort: gen postmarr= (_n==2)
by newid, sort: gen t1      = tf       if _n==_N
by newid, sort: replace t1  = marrdate if _n==1 & _N==2
by newid, sort: replace ts  = t1[_n-1] if _n==2 
by newid, sort: replace des = 0        if _n==1 & _N==2
gen marr=marrdate <= ts & tmar > 0    /*time-dependent dummy variable*/

list newid id des ts tf t1 tmar marrdate marr in 1/20

stset t1, failure(des) id(newid)    /*define single episode data*/

streg marr, dist(exp) nohr          /*fit parametric survival model*/

* percentage change in the rate: entry into marriage
display (exp(_b[marr])-1)*100       

log close