version 9
set scheme sj
capture log close
set more off
log using ehh2.log, replace

use rrdat1, clear

gen des = tfin ~= ti                /*destination state*/
gen tf  = tfin - tstart + 1         /*ending time*/

gen coho2 = tb >= 468 & tb <= 504   /*cohort 2*/
gen coho3 = tb >= 588 & tb <= 624   /*cohort 3*/
gen lfx   = tstart - te             /*labor force experience*/
gen pnoj  = noj - 1                 /*previous number of jobs*/

stset tf, failure(des)      /*define single episode data*/

streg edu coho2 coho3 lfx pnoj pres, dist(e)   /*Exponential model*/
predict residual, csnell     /*Cox-Snell residuals*/
stset residual, failure(des) /*define single episode data*/
sts gen km = s               /*generate Kaplan-Meier survivor function*/
generate cumhaz = -ln(km)    /*generate cumulative hazard*/
line cumhaz residual residual, sort name("exponential, replace") ///
legend(off) t1(Exponential) xtitle("")
drop cumhaz residual km

streg edu coho2 coho3 lfx pnoj pres, dist(weibull) /*Weibull model*/
predict residual, csnell
stset residual, failure(des)
sts gen km = s
generate cumhaz = -ln(km)
line cumhaz residual residual, sort name("weibull, replace") ///
legend(off) t1(Weibull) xtitle("")
drop cumhaz residual km

streg edu coho2 coho3 lfx pnoj pres, dist(llogistic) /*Log-logistic model*/
predict residual, csnell
stset residual, failure(des)
sts gen km = s
generate cumhaz = -ln(km)
line cumhaz residual residual, sort name("llogistic, replace") ///
legend(off) t1(Log-logistic) xtitle("")
drop cumhaz residual km

streg edu coho2 coho3 lfx pnoj pres, dist(lognormal) /*Log-normal model*/
predict residual, csnell
stset residual, failure(des)
sts gen km = s
generate cumhaz = -ln(km)
line cumhaz residual residual, sort name("lognormal, replace") ///
legend(off) t1(Log-Normal) xtitle("") 
drop cumhaz residual km

graph combine exponential weibull llogistic lognormal, /// 
l1(-ln(Kaplan-Meier)) b1(Cox-Snell residual) saving("Figure 8_2_1")

log close