version 9
capture log close
set more off
log using ehi5.log, replace

use rrdat1, clear

gen des   = tfin ~= ti               /*destination state*/
gen ts    = 0                        /*starting time*/
gen tf    = tfin - tstart + 1        /*ending time*/

gen coho2 = tb >= 468 & tb <= 504    /*cohort 2*/
gen coho3 = tb >= 588 & tb <= 624    /*cohort 3*/
gen lfx   = tstart - te              /*labor force experience*/
gen pnoj  = noj - 1                  /*previous number of jobs*/

gen marrdate = tmar- tstart
gen entrymarr = marrdate>0

gen newid = _n
expand 2 if entrymarr & marrdate <tf   /*episode splitting*/

by newid, sort: gen postmarr=(_n==2)
by newid, sort: gen t1=tf if _n==_N
by newid, sort: replace t1 = marrdate if _n==1 & _N==2
by newid, sort: replace ts = t1[_n-1] if _n==2 
by newid, sort: replace des=0 if _n==1 & _N==2
gen marr=marrdate <= ts & tmar >0

stset t1, failure(des) id(newid) 

gen marrmen= sex==1 & marrdate <= ts & tmar >0

stcox edu coho2 coho3 lfx pnoj pres marr marrmen, nohr  /*fit Cox proportional hazards model*/

log close